How to Auto Archive Declined Meetings to a Specific Calendar with Outlook VBA

Outlook will auto remove the meeting which you decline from your calendar. If you want to still save it, you can use the method introduced in this article.

By default, in Outlook, when you receive a meeting invitation, this meeting will be added to your calendar. However, as long as you select to decline it, Outlook will automatically delete it from the calendar at once. But sometimes actually you still desire to save it in another calendar, like a specific calendar named “Declined”. In this case, you can apply the following methods, which uses VBA, to quickly get it.

Auto Archive Declined Meetings to a Specific Calendar

Auto Archive Declined Meetings to a Specific Calendar

  1. To start with, you can launch your Outlook program.
  2. Then switch to “Developer” tab and click the “Visual Basic” button. Or press “Alt + F11” key shortcuts directly.
  3. Subsequently, you will get access to the Outlook VBA editor.
  4. Next you need to open a module that is not in use.
  5. After that, copy and paste the following codes into such a module.
Sub SaveDeclinedMeetingtoSpecificCalendar()
    Dim objMeetingRequest As MeetingItem
    Dim objMeeting As AppointmentItem
    Dim objMeetingResponse As MeetingItem
    Dim objCalendarFolder As Folder
    Dim objDeclinedMeeting As AppointmentItem
 
    Select Case Application.ActiveWindow.Class
           Case olInspector
                Set objMeetingRequest = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMeetingRequest = ActiveExplorer.Selection.Item(1)
    End Select
 
    If objMeetingRequest.Class = olMeetingRequest Then
       Set objMeeting = objMeetingRequest.GetAssociatedAppointment(True)
       'Save the meeting to be declined to a specific calendar
       Set objCalendarFolder = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar).Folders("Declined")
       Set objDeclinedMeeting = objCalendarFolder.Items.Add("IPM.Appointment")
       With objDeclinedMeeting
            .Subject = "Declined:" & objMeeting.Subject
            .Body = "Organized by: " & objMeeting.Organizer & vbCrLf & objMeeting.Body
            .Start = objMeeting.Start
            .End = objMeeting.End
            .Location = objMeeting.Location
            .Save
       End With
       'Decline the meeting
       Set objMeetingResponse = objMeeting.Respond(olMeetingDeclined)
       objMeetingResponse.Send
       objMeetingRequest.Delete
    End If
End Sub

VBA Codes - Auto Archive Declined Meetings to a Specific Calendar

  1. Later you can add the new macro to Quick Access Toolbar or home ribbon as usual.
  2. Moreover, you need to ensure that your Outlook is set to allow macros.
  3. Eventually, you can have a try.
  • Firstly, select a meeting request in your email list.
  • Then click the new macro button in Quick Access Toolbar.Try the new macro
  • At once, a declined response will be sent out. Now you can turn to open the specific calendar, in which you will see the declined meeting.Declined Meetings

Never Fear Outlook Crash

For Outlook, occasional crash is pretty common. Thus, if you have used Outlook for decades, you must have encountered such cases. As usual, everything will be still OK when you restart Outlook after crash. But if you find your PST file corrupt, do not panic. You still can get back the damaged PST data by an experienced tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including corrupted mdf and outlook repair software products. For more information visit www.datanumen.com

Comments are closed.