How to Always Open Outlook Meetings with “Scheduling Assistant” Page

There are two pages available in Outlook appointment and meeting window. One is “Appointment” page, and the other one is “Scheduling Assistant” page. If you want to always open meetings with “Scheduling Assistant” page, you can refer to this article.

When you access an appointment or meeting, the item window will open with the “Appointment” page. Maybe you have noticed that there is another page available. It’s “Scheduling Assistant” page. To be honest, the latter page is far more effective than the default one when creating and scheduling a new meeting. It is because that you can specify various details in “Scheduling Assistant” page more directly and intuitively.

Always Open Outlook Meetings with “Scheduling Assistant” Page

Thereby, many users hope to always open the meeting with the “Scheduling Assistant” page instead of the “Appointment” page. Looking at this requirement, here we’ll teach you how to realize it with Outlook VBA. As for how to run VBA code, you can refer to the article “How to Run VBA Code in Your Outlook”.

Always Open Outlook Meetings with “Scheduling Assistant” Page

  1. At the very outset, launch your Outlook program as usual.
  2. Then, access the Outlook VBA editor.
  3. Next, put the following VBA code into the “ThisOutlookSession” project.
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

'Occurs when you open an appointment
Private Sub objAppointment_Open(Cancel As Boolean)
    'If it is a meeting item
    If objAppointment.MeetingStatus = olMeeting Then
       With objAppointment
            .Recipients.ResolveAll
            'Open in "Scheduling Assistant" page
            .GetInspector.SetCurrentFormPage "Scheduling"
      End With
    End If
End Sub

VBA Code - Always Open Outlook Meetings with "Scheduling Assistant" Page

  1. After that, you can restart your Outlook to activate this macro.
  2. Since then, you can take a shot. No matter when you create a new meeting or open an existing meeting, the meeting will open in the “Scheduling Assistant” page instead of the default “Appointment” page.Outlook Meetings in “Scheduling Assistant” Page

Resolve Frequent Outlook Problems

It’s almost an unquestioned fact that Outlook is error prone. Therefore, many ask for mighty solutions which can fix various Outlook issues effectively. Generally, as soon as you encounter any troubles in Outlook, you can make use of the inner fix tool in the first place. However, if it fails, you can try a reliable external utility, like DataNumen Outlook Repair. It is able to find out the key issues and solve them in quick time and even get back maximum damaged Outlook data with ease.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including mdf recovery and outlook repair software products. For more information visit www.datanumen.com

Comments are closed.