2 Methods to View All Embedded Animated Gif Images of an Outlook Email in Animated Form

By default, the animated gif images embedded in the Outlook email are static, not animated. If you want to view them in animated form, you can utilize either of the following 2 means.

To embed animated gif images into email body, you can simply make use of “Insert Picture” feature in Outlook. However, you will discover that these embedded gif images are inactive, not animated. The same holds true for incoming emails. When you receive such an email that contains multiple gif images in body, if you would like to view them animatedly, you can refer to the following 2 approaches.

Method 1：View the Entire Email in Browser

1. To start with, in the Outlook window, double click on the source email which contains animated gif images in its body.
2. Then, in the opened Message window, you could click on the “Actions” button in “Move” group.
3. From the displaying drop down list, you can select “View in Browser” option.
4. Next, you will receive an alert like the following screenshot, in which you can just press “OK” button.
5. Immediately, the default browser on your computer will open this email.
6. At present, in this browser window, you will see that all the animated gifs are active.

By this means, the email textual contents will be shown in the browser as well. If you only would like to view the animated gif images actively, you can use the way below.

Method 2: View All Animated Gif Images Only in Browser

1. In the first place, press “Alt + F11” keys in the main Outlook screen.
2. Then, after getting into the “Microsoft Visual Basic for Applications” window, you can open an unused module or straightly insert a new module.
3. Next you can copy the following VBA code into this module.

Sub ViewAllAnimatedGifsActively()
    Dim objMail As Object
    Dim objAttachment As Outlook.Attachment
    Dim ColGifs As New Collection
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objHTMLFile As Object
    Dim objShell As Object
    Dim varGif As Variant
    Dim strContent As String
 
    'Get the source email
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objMail = Application.ActiveInspector.CurrentItem
    End Select
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemobject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objMail.Attachments
        'Save the embedded gif images
        If IsEmbeddedImage(objAttachment) = True Then
           If LCase(objFileSystem.GetExtensionName(objAttachment.filename)) = "gif" Then
              objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.filename
              ColGifs.Add objAttachment.filename
           End If
        End If
    Next
 
    'Input the details of saved gif images into a HTML file
    For Each varGif In ColGifs
        strContent = strContent & "<a href=""file://" & strTempFolder & "\" & varGif & """ target=""_new""><img src=""" & varGif & """ height=""" & "30%" & """ width=""" & "30%" & """ /></a>"
    Next
 
    Set objHTMLFile = objFileSystem.CreateTextFile(strTempFolder & "\Animated-Gifs.html")
    objHTMLFile.Write (strContent)
    objHTMLFile.Close
 
    'Open this HTML file
    Set objShell = CreateObject("WScript.Shell")
    objShell.Run strTempFolder & "\Animated-Gifs.html"
End Sub

Function IsEmbeddedImage(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedImage = True
    Else
       IsEmbeddedImage = False
    End If
End Function

4. Subsequently, for later convenient access, you’re better off adding this macro to Quick Access Toolbar.
5. Also, you have to check your Outlook macro setting to insure that macros are enabled.
6. Lastly, you can have a try.

• First, select or open an email.
• Then click on the new macro button in Quick Access Toolbar.
• At once, a new page will be opened in default internet browser, in which all the animated gif images are listed and active.

Recover Your Cherished Outlook Data

Given Outlook’s propensity to corruption, it has an inbox repair tool. Thus, when you encounter a severe crash, you can firstly recur to this tool. But do not pay too much hope on it. It is unable to fix seriously broken PST file. Hence, at that point, you can fall back on a more powerful reliable third party tool like DataNumen Outlook Repair. It has shouldered over its rivals due to high recovery rate.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including mdf repair and outlook repair software products. For more information visit www.datanumen.com