Как да използвам автоматично различни цветове на шрифта за отговаряне и препращане на имейли с Outlook VBA

Решения за Outlook Септември 29, 2025

По подразбиране не можете да позволите на Outlook автоматично да използва различни цветове на шрифта за отговор и препращане на имейли. Следователно, ако имате такова изискване, можете да прочетете тази стрost за да научите интелигентен подход.

Outlook ви позволява само да посочите шрифт, използван както за отговаряне, така и за препращане на имейли. Можете да отидете на „Файл“> „Опции“. След това в „Опции на Outlook“ се обърнете към раздела „Поща“ и кликнете върху бутона „Канцеларски материали и шрифтове ...“. В следващия прозорец можете да видите бутона „Шрифт“ в „Отговор или препращане на съобщения“. Щракнете върху него и след това можете да зададете специфичен цвят на шрифта за отговаряне и препращане на имейли.

Много потребители обаче се надяват да използват различни цветове на шрифтовете за отговор или препращане на имейли. Въпреки че Outlook не предоставя никакви директни функции за това, той все още може да бъде реализиран с VBA код. Сега прочетете, за да получите такова парче VBA код.

Автоматично използвайте различни цветове на шрифта за отговаряне и препращане на имейли

За катоtart, стартирайте приложението Outlook.
След това задействайте редактора на VBA с позоваване на „Как да стартирате VBA код във вашия Outlook".
След това, в съответствие с „Как да добавите Lib на обектrary Справка във VBA“, Добавете препратката към„ MS Word Object Librarу ”.
Впоследствие копирайте следния код в проекта “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

След това, резtart Outlook, за да активирате този макрос.
И накрая, можете да опитате.

Изберете или отворете имейл.
След това щракнете върху бутона „Отговор“. В отговор на имейл можете да въведете няколко думи в тялото. Цветът на шрифта трябва да е розов.
Или щракнете върху бутона „Отговор на всички“. В новата поща за „отговор на всички“ въведете думи в тялото. Цветът на шрифта със сигурност е зелен.
По същия начин щракнете върху бутона „Напред“. В препращащата поща новите думи ще бъдат показани в синьо.

Потърсете надежден софтуер

В случай на Корупция в Outlook, Мost потребителите са склонни да прибягват до софтуер за възстановяване на Outlook. На пазара има голямо количество такива програми. А някои от тях дори са безплатни. Въпреки това, трябва да се пазите от тези от неизвестни източници, тъй като те могат да влошат настоящия случай. Трябва да се възползвате от надежден и опитен инструмент, като DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден sql и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com