Как бързо да вмъкнете имена на получатели в тялото на имейла във вашия Outlook

Ако искате бързо да вмъкнете имената на получателите в тялото, когато съставяте имейл, можете да прочетете тази статия. Тук ще ви представим удобен метод.

Понякога може да се наложи да въведете имената на всички получатели в тялото, когато съставяте имейл. Несъмнено е значително досадно и тромаво да се извличат и вмъкват имената в тялото едно по едно ръчно. Ето защо, за да ви помогнем да го постигнете бързо, тук ще ви споделим ефикасно средство. Прочетете, за да получите подробните стъпки.

Вмъкнете имената на получателите в тялото на имейла

1. За катоtart, достъп до редактора на VBA чрез “Alt + F11”.
2. След това в прозореца „Microsoft Visual Basic for Applications“ активирайте „MS Word Object Library ”според„Как да добавите Lib на обектrary Справка във VBA".
3. След това копирайте VBA кода по-долу в празен модул.

Sub CopyRecipientNamesToBody()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim strRecipAddress As String
    Dim strRecipName As String
    Dim objContacts As Outlook.Items
    Dim i As Integer
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim strRecipNames As String
    Dim objMailDocument As Word.Document
 
    'Get the current email
    Set objMail = Application.ActiveInspector.CurrentItem
    objMail.Recipients.ResolveAll
 
    For Each objRecipient In objMail.Recipients
        strRecipAddress = objRecipient.Address
 
        'Get the corresponding contact name
        Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
        For i = 1 To 3
            strFilter = "[Email" & i & "Address] = " & strRecipAddress
            Set objFoundContact = objContacts.Find(strFilter)
            If Not (objFoundContact Is Nothing) Then
               strRecipNames = strRecipNames & objFoundContact.FullName & vbCr
               Exit For
            End If
        Next
 
        'If there isn't associated contact
        'Extract name from email address
        If objFoundContact Is Nothing Then
           strRecipName = Split(strRecipAddress, "@")(0)
           strRecipName = UCase(Left(strRecipName, 1)) & Right(strRecipName, Len(strRecipName) - 1)
           strRecipNames = strRecipNames & strRecipName & vbCr
        End If
    Next
 
    'Insert the names at the beginning of email
    Set objMailDocument = objMail.GetInspector.WordEditor
    objMailDocument.Range(0, 0).InsertAfter strRecipNames
End Sub

3. След това добавете този макрос към лентата с инструменти за бърз достъп на прозореца за съобщения съгласно незадължителната стъпка в „Как да стартирате VBA код във вашия Outlook".
4. След това излезте от прозореца.
5. Накрая направете изстрел.

• Първо, съставете имейл и попълнете получателите.
• След това натиснете бутона за макрос в лентата с инструменти за бърз достъп.
• Когато макросът завърши, имената на получателите са вмъкнати в тялото на имейла, както е показано на фигурата по -долу.

Пазете се от щети в Outlook

Тъй като Outlook е уязвим, е трудно да се защити Outlook от повреда. Без съмнение трябва да сте склонни да се сблъскате PST корупция. Затова е по -добре да вземете някои ефективни предпазни мерки. Например, трябва да правите последователни архиви на данни за Outlook, да сте запознати с това как да използвате инструмента за поправка на входящи кутии, както и да държите в близост мощен външен инструмент, като например DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително SQL Server фиксира и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com