Bütün faylları necə tez çap etmək olar Zip Outlook e-poçtunun əlavəsi

Bir çox istifadəçi a formatında sıxılmış bütün faylları çap etməyə ümid edir zip Outlook e-poçtunu çətinliklə saxlamadan və sıxışdırmadan əlavə edin zip qoşma. Beləliklə, bu məqalə onu həyata keçirmək üçün daha təsirli bir vasitə təqdim edəcəkdir.

Çap etmək istədiyiniz zaman a zip qoşma, siz onun üzərinə yerləşdirməyə və lentdəki “Tez Çap” düyməsini klikləməyə alışmış ola bilərsiniz. Bununla belə, bu vasitə ilə Outlook yenə də sizdən yadda saxlamağı və söndürməyi xahiş edəcəkzip ilk növbədə o. Bu bezdirici addımların qarşısını almaq istəyirsinizsə, aşağıdakı VBA kodundan istifadə edə bilərsiniz.

Bütün faylları çap edin Zip E-poçtun əlavəsi

1. Başlamaq üçün, start Outlook proqramınız.
2. Sonra məqalədə göstərilən addımları yerinə yetirərək Outlook VBA redaktoruna giriş əldə edin – “Outlook-da VBA kodunu necə işlətmək olar".
3. Sonra, "ThisOutlookSession" layihəsini və ya istifadə olunmamış modulu aça bilərsiniz.
4. Sonra, aşağıdakı VBA kodunu kopyalayın və yapışdırın.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Bundan sonra cari VBA redaktoru pəncərəsini bağlayın.
6. Daha sonra, Sürətli Giriş Alətlər Panelinə yeni makro əlavə etmək üçün Outlook Seçimlərinə keçin.
7. Nəhayət, bir çəkiliş edə bilərsiniz:

• Əvvəlcə a seçin zip e-poçt əlavəsi.
• Sonra, Tez Giriş Alətlər Panelində makroya klikləyin.

8. Bir anda, fayllar seçilmişdə sıxılır zip əlavə çap olunacaq.

Outlook məlumat fayllarının ehtiyat nüsxəsini çıxarın

Outlookun korrupsiyaya meylli olduğunu kəşf etmiş ola bilərsiniz. Outlook zədələndikdən sonra Outlook məlumatlarınız l olacaqost. Beləliklə, Outlook məlumat fayllarınızın müntəzəm ehtiyat nüsxəsini çıxarmaq vacibdir ki, Outlook məlumatlarını ehtiyat nüsxələri vasitəsilə asanlıqla əldə edə biləsiniz. Ancaq ehtiyat nüsxəsinin bir neçə həftəlik olduğunu və səmərəsiz olduğunu görsəniz, etibarlı və təcrübəli bir nüsxəyə müraciət etməkdən başqa çarəniz yoxdur. PST bərpası kimi alət DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com