Windows Qovluğundakı Bütün Outlook Mesaj Fayllarından Qoşmaları Necə Tez Çıxarmaq olar

Ola bilsin ki, siz Windows qovluğunda .msg formatında çoxlu Outlook e-poçtlarını saxlamısınız. Və daha sonra, bu fayllardan əlavələri çıxarmaq istəyirsinizsə, bu məqalədə paylaşılan üsuldan istifadə edə bilərsiniz.

Outlook-da e-poçtlardan əlavələri çıxarmaq olduqca asandır. Bəs Windows qovluğunda .msg faylları kimi ixrac edilmiş e-poçtlar haqqında nə demək olar? Ümumiyyətlə, siz əvvəlcə bu .msg fayllarını Outlook-da açmalı və sonra onlardan bir-bir qoşmaları saxlamalısınız. Bəlkə də bunu çox çətin hiss edəcəksiniz. Beləliklə, bundan sonra sizə daha sürətli bir həll yolu öyrədəcəyik.

Windows Qovluğundakı Bütün Outlook Mesaj Fayllarından Qoşmaları çıxarın

1. Başlamaq üçün, start Outlook proqramınızı işə salın və VBA redaktorunu işə salın.
2. Sonra “Proqramlar üçün Microsoft Visual Basic” pəncərəsində aşağıdakı VBA kodunu istifadə olunmamış modula köçürün.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Sonra kursoru birinci alt proqrama keçirin və "F5" düyməsini basın.
4. Bundan sonra, açılan informasiya qutusunda mənbə Windows qovluğunu seçməyiniz tələb olunacaq.
5. "OK" düyməsini basdıqdan sonra makro işləməyə davam edəcək.
6. Tamamlandıqda, "Tamamlandı" mesajını alacaqsınız.
7. İndi çıxarılmış qoşmaları saxlamaq üçün əvvəlcədən təyin edilmiş yerli qovluğa giriş əldə edə bilərsiniz.

Outlook problemlərini səmərəli şəkildə həll edin

Outlook səhvə meylli olduğundan, Outlook obyektləri ilə işləyərkən ehtiyatlı olmalısınız, məsələn, naməlum e-poçtlara daxil edilmiş fayllara və ya keçidlərə heç vaxt etibar etməmək və s. Əks halda, Outlook faylınız asanlıqla xarab ola bilər. Bu vəziyyətdə, hətta daxili düzəltmə aləti də çox kömək etməyəcək. Müraciət edə biləcəyiniz yalnız təcrübəli bir xarici yardım proqramıdır DataNumen Outlook Repair. Mümkündür PST-ni düzəldin asanlıqla fayl.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş sql və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com