Outlook-da E-poçtun Kateqoriyalarını Onun Bütün Cavablarına və Forvardlarına Avtomatik Tətbiq Etmək

E-poçtu cavablandırarkən və ya yönləndirərkən eyni kateqoriyaları tətbiq etmək istəyə bilərsiniz. Bu yazıda sizə bunu VBA kodu ilə həyata keçirməyi öyrədəcəyik.

Orijinal e-poçtun bütün cavablarına və göndərişlərinə eyni rəngli kateqoriyalar təyin etməyə vərdiş etmisinizsə, niyə Outlook-un avtomatik olaraq buna nail olmasına icazə vermirsiniz? Outlook belə birbaşa funksiyanı təmin etməsə də, siz yenə də VBA kodunun köməyi ilə onu əldə edə bilərsiniz. Aşağıda ətraflı addımları və kodu sizə təqdim edəcəyik.

E-poçtun Kateqoriyalarını Onun Bütün Cavablarına və Göndərmələrinə Avtomatik Tətbiq edin

1. Ən başlanğıcda Outlook proqramını işə salın.
2. Sonra Outlook VBA redaktorunu işə salmaq üçün “Alt + F11” düymələrini basın.
3. Sonra, aşağıdakı VBA kodunu “ThisOutlookSession” layihəsinə köçürün.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Bundan sonra, restarBu layihəni aktivləşdirmək üçün Outlook-a daxil olun.
5. O vaxtdan bəri, aşağıdakı addımları izləyərək cəhd edə bilərsiniz.

• Əvvəlcə e-poçtu seçin və "İrəli" düyməsini basın.
• Sonra, "Seçimlər" sekmesine keçə və "Ətraflı Seçimlər" qrupunun aşağı sağ küncündəki genişləndirmə işarəsini vura biləcəyiniz yönləndirmə e-poçtu görünəcək.
• Bundan sonra, açılan "Xüsusiyyətlər" informasiya qutusunda bu e-poçtun orijinal e-poçtla eyni rəng kateqoriyaları ilə təyin olunduğunu görə bilərsiniz.

Zədələnmiş Outlook faylını düzəldin

Outlook-un həssas olduğunu nəzərə alaraq, Outlook məlumat itkisinin qarşısını almaq üçün bir çox tədbirlər görməlisiniz. Məsələn, məlumatların vaxtaşırı ehtiyat nüsxəsini çıxarmaq lazımdır. Bundan əlavə, daxil edilmiş bağlantılar və ya əlavələr daxil olmaqla naməlum e-poçtlardan ehtiyatlı olmalısınız. Nəhayət, ən azı, ən yaxşı xarici düzəltmə alətinə sahib olmalısınız, məsələn DataNumen Outlook Repair. Bu, maksimum məlumat əldə etməyə kömək edə bilər korlanmış Outlook file.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc SQL Server düzeltmek və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com